Optional propagate

// Sometimes a function cannot do anything useful with a missing value except
// report that it is missing too. How far ahead is #7 of #10? If either player
// is unknown, there is no answer, and the honest result is `none`.
//
// Writing that with `match` takes two nested matches and two `none` arms that
// say the same thing. A `?` after an optional says it for you:
//
//     ScoreOf(players, a)?
//
// If the optional is present, this is the `int` inside it. If it is `none`, the
// function returns `none` straight away, and nothing after it runs. So `?` can
// only appear in a function whose own result is optional: it needs a `none` it
// can return.
import Io::PrintLine;

struct Player {
    number: int;
    score: int;
}

func ScoreOf(players: Player[..], number: int) -> int? {
    for player in players {
        if player.number == number {
            return player.score;
        }
    }
    return none;
}

// Both scores are needed, and either may be missing. The `?`s let the sum be
// written as if they were plain numbers.
func Lead(players: Player[..], a: int, b: int) -> int? {
    return ScoreOf(players, a)? - ScoreOf(players, b)?;
}

// `?` works anywhere in the function, including in a `let`. Each line either
// produces its value or ends the function.
func TeamTotal(players: Player[..], numbers: int[..]) -> int? {
    var total = 0;
    for number in numbers {
        let score = ScoreOf(players, number)?;
        total += score;
    }
    return total;
}

func Main() -> int {
    let players = [
        Player { number: 4, score: 8 },
        Player { number: 7, score: 12 },
        Player { number: 10, score: 25 }
    ];

    // The caller is where absence is finally handled, with `match` or `??`.
    match Lead(players, 10, 7) {
        lead? => PrintLine("#10 leads #7 by {}", lead),
        none => PrintLine("no answer")
    }
    match Lead(players, 10, 3) {
        lead? => PrintLine("#10 leads #3 by {}", lead),
        none => PrintLine("#10 against #3: no answer, #3 is not on the team")
    }

    let starters = [ 4, 7, 10 ];
    let mixed = [ 4, 9, 10 ];
    PrintLine("starters total: {}", TeamTotal(players, starters) ?? -1);
    PrintLine("mixed total:    {}", TeamTotal(players, mixed) ?? -1);

    // Watch out: `?` is not available in `Main`, or in any function that
    // returns a plain `int`. There is no `none` to hand back, so the compiler
    // rejects it. Use `match` or `??` there instead.
    return 0;
}