Iterable

// The Iterator lesson walked a countdown, which is used up as it goes. A collection is different:
// a shelf of books can be looked through any number of times, and looking does not use up the
// books.
//
// So a collection does not walk itself. It provides one method,
//     func Iterate(self: &T) -> SomeIterator
// which hands out a fresh iterator, starting at the beginning, every time it is called. `for`
// calls it once at the top of each loop and then drives that iterator with `Next`. The collection
// is only borrowed, so it is unchanged afterwards; the position lives in the iterator.
//
// As with `Iterator`, Core's `Iterable` interface lists no methods and only names the role.
import Core::{ Iterable, Iterator };
import Io::{ Print, PrintLine };

struct Shelf {
    titles: char8[..][4];
}

// The iterator: a view of the shelf's titles, and how far along it has got.
struct ShelfCursor {
    titles: char8[..][..];
    index: uint;
}

extend ShelfCursor : Iterator {
    func Next(self: &var ShelfCursor) -> char8[..]? {
        if self.index == self.titles.length {
            return none;
        }
        let title = self.titles[self.index];
        self.index += 1;
        return title;
    }
}

extend Shelf : Iterable {
    func Iterate(self: &Shelf) -> ShelfCursor {
        return ShelfCursor { titles: self.titles[..], index: 0 };
    }
}

func Main() -> int {
    let shelf = Shelf { titles: ["Dune", "Emma", "Ulysses", "Beloved"] };

    Print("on the shelf:");
    for title in shelf {
        Print(" {}", title);
    }
    PrintLine();

    // A second loop gets a second iterator, so it starts from the first book again.
    var letters: uint = 0;
    for title in shelf {
        letters += title.length;
    }
    PrintLine("letters in all titles: {}", letters);

    // Two iterators from one shelf keep separate positions.
    var reader = shelf.Iterate();
    var browser = shelf.Iterate();
    reader.Next();
    reader.Next();
    PrintLine("one reader is at {}, the other at {}", reader.Next() ?? "", browser.Next() ?? "");
    return 0;
}